Displaying Sentence Word Counts with VBA

You can configure Word's grammar checker to show the average number of words per sentence in a document. That's useful because you don't want a document to have many long sentences. However, in a long document it's also important to have a variety of sentence lengths, but the grammar checker can't help you with this.

To see the lengths of the sentences in a document, use the VBA code in the following listing:

Sub DisplaySentenceLengths()

Dim s As Range

Dim maxWords As Integer

Dim i As Integer

Dim sentenceLengths() As Integer

Dim str As String

With ActiveDocument

'

' Run through all the sentences to find the longest

'

maxWords = 0

For Each s In .Sentences

If CountWords(s) > maxWords Then

maxWords = CountWords(s)

End If

Next 's

'

' Redimension the array of sentence lengths

'

ReDim sentenceLengths(maxWords)

'

' Run through the sentences again to count

' the number of sentences for each length

'

For Each s In .Sentences

'

' Get the word count for the sentence

'

j = CountWords(s)

'

' If it's not empty, add it to the array

'

If j > 0 Then

sentenceLengths(j - 1) = sentenceLengths(j - 1) + 1

End If

Next 's

'

' Construct the string that displays the sentence lengths

' and their frequencies

'

str = "Sentence Length:" & vbTab & "Frequency:" & vbCrLf & vbCrLf

'

' The UBound() function tells you the upper bound of an array.

' In this case, it tells you the largest value in sentenceLengths.

'

For i = 0 To UBound(sentenceLengths) - 1

'

' Build the string

'

str = str & IIf(i + 1 < 10, " ", "") & i + 1 & \_

IIf(i = 0, " word: ", " words: ") & \_

vbTab & vbTab & sentenceLengths(i) & vbCrLf

Next 'i

'

' Display the string

'

MsgBox str

End With

End Sub

Function CountWords(countObject As Object) As Long

Dim i As Long, word As Range

i = 0

For Each word In countObject.Words

Select Case Asc(Left(word, 1))

Case 48 To 57, 65 To 90, 97 To 122

i = i + 1

End Select

Next 'word

CountWords = i

End Function

Using the ActiveDocument object, the macro makes a first pass through all the sentences to find the one with the most words. Notice that the procedure uses the CountWords function to get accurate word counts for each Sentence object. The macro then uses this maximum word count to redimension the sentenceLengths array, which is used to hold the number of occurrences of each sentence length within the document. To calculate these frequencies, the macro then runs through all the sentences again and increments the array values for each length. The macro finishes by constructing and then displaying a string that holds the sentence lengths and frequencies.

**Tip:** To display word count data for each paragraph, instead of each sentence, replace .Sentences in the listing with .Paragraphs.